 |
Das deutsche QBasic- und FreeBASIC-Forum
Für euch erreichbar unter qb-forum.de, fb-forum.de und freebasic-forum.de!
|
| Vorheriges Thema anzeigen :: Nächstes Thema anzeigen |
| Autor |
Nachricht |
Jet X
gesperrt
Anmeldungsdatum: 05.01.2005
Beiträge: 447
|
 Verfasst am: 17.03.2005, 17:24 Titel: Fenster in QBasic Programieren..... |
 |
|
Wie Programmiere ich Fenster für Windows in QBasic die
richtige Bottons haben ? Wenn man das Programm startet sollte nicht ein großes schwarzes Fenster startet und dann eine Grafische Oberfläche in screen 12 oder 13 mit einer mausrotine sonder es sollte sich ein richtiges
Fenster öffnen ! Ist so was in Qbasic möglich ? Kleines Beispiel währe gut !!!!
Also Grüße Jet X
PS: Habe Angefangen mein Eigenes Os zu Programmieren und
bin noch auf keine Probleme gestoßen ! 
_________________
Courage ist gut, aber Ausdauer ist besser. |
|
| Nach oben |
|
 |
jb
Anmeldungsdatum: 14.01.2005
Beiträge: 2010
|
| Verfasst am: 17.03.2005, 17:30 Titel: |
|
|
| Jet X hat Folgendes geschrieben: |
Bottons
|
Es heißt Buttons, nur so nebenbei.
Richtige Fenster sind meines Wissens mit QB nur sehr schwer realisierbar,
--> steige auf VisualBasic um.
jb |
|
| Nach oben |
|
|
Jet X
gesperrt
Anmeldungsdatum: 05.01.2005
Beiträge: 447
|
| Verfasst am: 17.03.2005, 17:40 Titel: |
|
|
Wow ! Hat mir sehr geholfen ! 
_________________
Courage ist gut, aber Ausdauer ist besser. |
|
| Nach oben |
|
|
helium
Anmeldungsdatum: 10.09.2004
Beiträge: 397
Wohnort: Leverkusen
|
| Verfasst am: 17.03.2005, 18:17 Titel: |
|
|
| Zitat: | Wie Programmiere ich Fenster für Windows in QBasic die
richtige Bottons haben ? Wenn man das Programm startet sollte nicht ein großes schwarzes Fenster startet und dann eine Grafische Oberfläche in screen 12 oder 13 mit einer mausrotine sonder es sollte sich ein richtiges
Fenster öffnen !
|
Wenn du ein OS schreiben willst, ist es natürlich sehr sinnvoll die Fenster eines anderen Betriebsystems zu verwenden 
| Zitat: | | Ist so was in Qbasic möglich ? |
Nein.
PS: Vor Fragezeichen und anführungszeichen gehört kein Leerzeichen!
_________________
Bevor Sie aufhören sich körperlich zu betätigen sollten Sie ihren Doktor befragen. Körperliche Inaktivität ist abnormal und gefährlich für Ihre Gesundheit. |
|
| Nach oben |
|
|
marzec
Anmeldungsdatum: 13.10.2004
Beiträge: 267
|
| Verfasst am: 17.03.2005, 18:39 Titel: Re: Fenster in QBasic Programieren..... |
|
|
| Jet X hat Folgendes geschrieben: | | Ist so was in Qbasic möglich ? Kleines Beispiel währe gut !!! |
wie schon von helium gesagt, nein es ist nicht möglich, da fenster über die sogenannte windows api erzeugt und gesteuert werden und du von DOS aus keinen zugriff darauf hast.
kleiner duden WÄRE gut.
_________________
Yagl - yet another gameprogramming library |
|
| Nach oben |
|
|
jb
Anmeldungsdatum: 14.01.2005
Beiträge: 2010
|
| Verfasst am: 17.03.2005, 19:21 Titel: |
|
|
| Jet X hat Folgendes geschrieben: |
Wow ! Hat mir sehr geholfen !
|
Was willst du eigentlich?!
Soll ich dich vielleicht anlügen?
Denk mal über deine Ausdrucksweise nach!
jb |
|
| Nach oben |
|
|
Sebastian
Administrator
Anmeldungsdatum: 10.09.2004
Beiträge: 5969
Wohnort: Deutschland
|
|
| Nach oben |
|
|
Paul
aka ICC, HV-Freak
Anmeldungsdatum: 11.09.2004
Beiträge: 588
Wohnort: Uelzen
|
| Verfasst am: 17.03.2005, 20:19 Titel: |
|
|
Ich mach vor einem Ausrufe- oder Fragezeichen IMMER ein Leerzeichen !   Und das wird auch so bleiben
@Jet X:
Wenn du von einer GUI in QB redest:
Du musst halt jede Kleinigkeit einprogrammieren. Du legst einen Array fest, in dem alle Daten eines Fenster vorhanden sind. Das gleiche machst du mit allen Objekten (Buttons, Testboxen etc.). Dann kommen Routinen zur Fensterverwaltung dazu, z.B. Neues Fenster erstellen, Fenster schließen (=löschen), Routinen zum Buttonabfragen.
Wenn du von einer GUI in Windows redest: vergiss es
| Zitat: | PS: Habe Angefangen mein Eigenes Os zu Programmieren und
bin noch auf keine Probleme gestoßen ! |
[ ... ]
_________________
 |
|
| Nach oben |
|
|
jb
Anmeldungsdatum: 14.01.2005
Beiträge: 2010
|
| Verfasst am: 17.03.2005, 20:26 Titel: |
|
|
| Jet X hat Folgendes geschrieben: |
--OS Vorstellung--
JET X SYSTMEM
Jet X Systems ist zwar noch voll in Arbeit aber ich wollte es schon
mal ankündigen :
Hier die Features :
[...]
- Keine Grafischenbenutzeroberflächen
|
Häh? Wie sollen wir das denn jetzt verstehen? :fragezeichen:
jb |
|
| Nach oben |
|
|
Sebastian
Administrator
Anmeldungsdatum: 10.09.2004
Beiträge: 5969
Wohnort: Deutschland
|
|
| Nach oben |
|
|
jb
Anmeldungsdatum: 14.01.2005
Beiträge: 2010
|
| Verfasst am: 17.03.2005, 22:01 Titel: |
|
|
Ihr habt Probleme!
Wie wär's mit dem neuen Trash-Forum????
jb |
|
| Nach oben |
|
|
Thomas Antoni
Anmeldungsdatum: 12.10.2004
Beiträge: 220
Wohnort: Erlangen
|
| Verfasst am: 18.03.2005, 17:13 Titel: ... |
|
|
Der erste Schritt zu einem Fenster ist das Anzeigen eines Textes in einem Rahmen. Fang erst mal damit an. Alles andere kannst Du dann nach und nach dazubasteln.
Zu Textrahmen-Fenstern habe ich mir für die QB-MonsterFAQ Folgendes vorgemerkt:
--------------------------------------------------------------------------------
Frage deutsch
~~~~~~~~~~~~~~
Wie zeige ich einen Kasten im Textmodus an?
oder
Wie zeichne ich einen Rahmen um einen Text?
Question English
~~~~~~~~~~~~~~
How to display a box with of text characters?
Antwort 1
~~~~~~~~~
[ von Thomas Antoni, 4.3.2004 ]
Da kannst Du Dich an meinem folgenden Programm BOX.BAS orientieren, das einen
Kasten aus Doppelliniensymbolen auf den Textbildschirm zeichnet.
Die zum Zeichnen von Kästen in Frage kommenden ASCII-Zeichen kannst Du aus der
ASCII-Tabelle entnehmen, die in der QBasic-Onlinehilfe unter "Hilfe | Inhalt |
ASCII-Zeichen-Codes " zur Verfügung steht.
| Code: |
'******************************************************************
' BOX.BAS = Zeichnen eines Kastens aus Doppelstrichen im Textmodus
' =======
' Dieses QBasic-Programm enthaelt die SUB DrawBox, die einen einen
' Kasten aus Doppelliniensymbolen auf den Bildschirm zeichnet.
' Der linke obere Eckpunkt (x1|y1) und der rechte untere Eckpunkt
' (x2|y2) sind waehlbar.
'
' (c) Thomas Antoni, 4.3.2004
'******************************************************************
DECLARE SUB DrawBox (x1%, y1%, x2%, y2%)
CLS
INPUT "Mit welcher Spalte soll der Kasten beginnen (1...80) ", x1%
INPUT "Mit welcher Zeile soll der Kasten beginnen (1...25) ", y1%
INPUT "Mit welcher Spalte soll der Kasten enden (1...80) ", x2%
INPUT "Mit welcher Zeile soll der Kasten enden (1...25) ", y2%
COLOR 10
CALL DrawBox(x1%, y1%, x2%, y2%) 'gruenen Kasten zeichnen
COLOR 7 'Hellgraue Vordergrundfarbe wieder herstellen
SUB DrawBox (x1%, y1%, x2%, y2%)
'---- ASCII-Zeichen fuer die Doppel-Kastensymbole
LO$ = CHR$(201) 'Linke obere Ecke
LU$ = CHR$(200) 'Linke untere Ecke
RO$ = CHR$(187) 'Rechte obere Ecke
RU$ = CHR$(188) 'Rechte untere Ecke
WA$ = CHR$(205) 'Waagerechter Doppelstrich
SE$ = CHR$(186) 'Senkrechter Doppelstrich
'---- oberen Kastenrand anzeigen
LOCATE y1%, x1%
PRINT LO$; STRING$(x2% - x1% - 1, WA$); RO$
'---- seitliche Kastenraender anzeigen
FOR y% = y1% + 1 TO y2% - 1
LOCATE y%, x1%: PRINT SE$
LOCATE y%, x2%: PRINT SE$
NEXT
'---- unteren Kastenrand anzeigen
LOCATE y2%, x1%
PRINT LU$; STRING$(x2% - x1% - 1, WA$); RU$
END SUB
|
(( BOX.BAS bereits in /progs/neu/ ))
Weitere sehr gut aussehende Kästen, zum Teil mit runden Ecken, findest Du in
meinem Programm KAESTEN.BAS, das auf www.qbasic.de unter (Download | Eigene
Progs" zum Herunterladen bereitsteht.
Aus dem obenstehenden Programm BOX.BAS habe ich mein folgendes Programm
BOX_SCHA.BAS abgeleitet, das sogar einen Kasten
mit Schatteneffekt auf den Bildschirm zaubert:
| Code: |
'******************************************************************
' BOX_SCHA.BAS = Zeichnen eines Kastens im Textmodus mit Schatten
' ============
' Dieses QBasic-Programm enthaelt die SUB DrawSBox, die einen
' Kasten aus Liniensymbolen mit Schatteneffekt auf den Bildschirm
' zeichnet.
' Der linke obere Eckpunkt (x1|y1) und der rechte untere Eckpunkt
' (x2|y2) sind waehlbar. Die Farbe des Kasten-Vorder- und
' -Hintergrundes muss bzw. kann im Anwenderprogramm gewählt
' werden.
'
' (c) Thomas Antoni, 4.3.2004
'******************************************************************
DECLARE SUB DrawBox (x1%, y1%, x2%, y2%)
CLS
INPUT "Mit welcher Spalte soll der Kasten beginnen (1...80) ", x1%
INPUT "Mit welcher Zeile soll der Kasten beginnen (1...25) ", y1%
INPUT "Mit welcher Spalte soll der Kasten enden (1...80) ", x2%
INPUT "Mit welcher Zeile soll der Kasten enden (1...25) ", y2%
COLOR 9, 11 'hellblau auf türkis
CALL DrawBox(x1%, y1%, x2%, y2%) 'Kasten zeichnen
COLOR 7, 0 'hellgrau auf schwarz wieder herstellen
'
SUB DrawBox (x1%, y1%, x2%, y2%)
'***************************************************************
' SUB DrawBox - Zeichnet einen Kasten mit Schatten im Textmodus
' ===========
' Uebergeben werden die Koordinaten des linken oberen Eckpunktes
' (x1% | y1%) und des rechten unteren Eckpunktes (x2% | y2%)
'
' (c) Thomas Antoni, 3.4.2004
'***************************************************************
'
'---- ASCII-Zeichen fuer die Doppel-Kastensymbole
LO$ = CHR$(218) 'Linke obere Ecke
LU$ = CHR$(192) 'Linke untere Ecke
RO$ = CHR$(191) 'Rechte obere Ecke
RU$ = CHR$(217) 'Rechte untere Ecke
WA$ = CHR$(196) 'Waagerechter Strich
SE$ = CHR$(179) 'Senkrechter Strich
SCH$ = CHR$(219) 'Schatten
'
'---- oberen Kastenrand anzeigen
LOCATE y1%, x1%
PRINT LO$; STRING$(x2% - x1% - 1, WA$); RO$
'
'---- seitliche Kastenraender anzeigen
FOR y% = y1% + 1 TO y2% - 1
LOCATE y%, x1%
PRINT SE$; SPACE$(x2% - x1% - 1); SE$; SCH$; SCH$
NEXT
'
'---- unteren Kastenrand anzeigen
LOCATE y2%, x1%
PRINT LU$; STRING$(x2% - x1% - 1, WA$); RU$; SCH$; SCH$
'
'---- Unteren Schatten anzeigen
LOCATE , x1% + 2
PRINT STRING$(x2% - x1% + 1, SCH$)
END SUB
|
(( BOX_SCHA.BAS bereits in /progs/neu/ ))
Antwort 2
~~~~~~~~~~~~
[ von Juergen Schroeder ( Schroeder@Starcke.de ) per Mail, 19.6.2003 ]
Hans-Jürgen Schröder hat mir ( Thomas Antoni) ein sehr flexibles Programm zum
Malen eines Kastens im Textmodus gemailt. Im Folgenden Hans-Jürgens Mail und das
Programm-Listing:
Hallo lieber Thomas!
Seit nun fast 2 Jahren bin ich ein häufiger Besucher Deiner Web-Seite. Es ist
immer spannend und aktuell in dem QB-Forum herumzustöbern oder sich über das
Neuste von Q(uick)Basic zu informieren. Ich habe mir auch schon viele
Programmbeispiele von Deiner Seite heruntergeladen. Bei Programmierproblemen wird
man schnell und kompetent von der Q(uick)Basic-Gemeinde geholfen, bzw. man kann
selbst jemanden unterstützen. Ist wirklich eine tolle Sache.
Nun zum Thema, weswegen ich Dir maile. In meiner Firma arbeiten wir auch mit
Basic und zwar mit Business Basic von der ehemaligen Firma Nixdorf, Paderborn.
Hier hat man zwar mehr Möglichkeiten was Dateizugriffe anbelangt, aber für den
Privatbereich reicht QB voll aus. Nun habe ich ein kleines Programm in Business
Basic geschrieben um eine Eingabemaske zu gestalten. Dabei kann ein Rahmen in
unterschiedlichen Größen und Positionen auf dem Bildschirm angezeigt werden.
Nach Fertigstellung und fehlerfreiem Test habe ich mir gedacht, das kannst Du ja
auch in QuickBasic umschreiben und Thomas Antoni für seine QB-MonsterFAQ zur
Verfügung stellen, damit vielleicht auch andere etwas davon haben. Im Anhang
stelle ich Dir das Programm gerne frei zur Verfügung.
Mit freundlichen Grüßen
Jürgen Schröder
THU, 19. Juni 2003
| Code: |
'*****************************************************************
' RAHMEN.BAS - Zeichnen eines Rahmens aus Textzeichen mit
' ========== konfigurbarer Groesse und Farben
'
' Variables Programm zum Zeichnen eines Rahmens in verschiedenen
' Farben. Anzuwenden in Textmodus Screen 0.
' Die im Kommentar mit ? versehenen Variablen koennen Sie Ihren
' Wuenschen entsprechend anpassen.
'
' (c) Juergen Schroeder
'*****************************************************************
CLS
Zeile% = 5 ' Beginn des Rahmens ab Zeile ?
Spalte% = 10 ' Beginn des Rahmens ab Spalte ?
Breite% = 60 ' Breite des Rahmens ?
Hoehe% = 3 ' Hoehe des Rahmens ?
VFarbe% = 14 ' Vordergrundfarbe = gelb ?
HFarbe% = 0 ' Hintergrundfarbe = schwarz ?
'
IF Spalte% + Breite% > 79 THEN GOTO FEHLER1
IF Zeile% + Hoehe% > 23 THEN GOTO FEHLER2
'
COLOR VFarbe%, HFarbe%
'
Z1$ = "Ú" ' linke obere Ecke
Z2$ = "Ä" ' waagerechter Strich
Z3$ = "¿" ' rechte obere Ecke
Z4$ = "³" ' senkrechter Strich
Z5$ = "À" ' linke untere Ecke
Z6$ = "Ù" ' rechte untere Ecke
'
'--- Zeichnen des Rahmens ---
LOCATE Zeile%, Spalte%: PRINT Z1$
FOR Zaehler% = 1 TO Breite%
LOCATE Zeile%, Spalte% + Zaehler%: PRINT Z2$
NEXT Zaehler%
LOCATE Zeile%, Spalte% + Breite% + 1: PRINT Z3$
FOR Zaehler% = 1 TO Hoehe% - 1
LOCATE Zeile% + Zaehler%, Spalte% + Breite% + 1: PRINT Z4$
NEXT Zaehler%
LOCATE Zeile% + Hoehe%, Spalte% + Breite% + 1: PRINT Z6$
FOR Zaehler% = Breite% TO 1 STEP -1
LOCATE Zeile% + Hoehe%, Spalte% + Zaehler%: PRINT Z2$
NEXT Zaehler%
LOCATE Zeile% + Hoehe%, Spalte%: PRINT Z5$
FOR Zaehler% = Hoehe% - 1 TO 1 STEP -1
LOCATE Zeile% + Zaehler%, Spalte%: PRINT Z4$
NEXT Zaehler%
GOTO EOJ
'
FEHLER1:
COLOR 4:
LOCATE 11, 10: PRINT "Fehler-1:":
LOCATE 12, 10: PRINT "Die Breite des Rahmens ist zu lang,":
LOCATE 13, 10: PRINT "bzw. die Startposition (Spalte%) ist falsch":
GOTO EOJ
'
FEHLER2:
COLOR 4:
LOCATE 11, 10: PRINT "Fehler-2:":
LOCATE 12, 10: PRINT "Die Hoehe des Rahmens ist zu lang,":
LOCATE 13, 10: PRINT "bzw. die Startposition (Zeile%) ist falsch":
'
EOJ:
COLOR 7, 0 ' Auf Standardfarben zuruecksetzen
END
|
((RAHMEN.BAS bereits in qbmonfaq/progs/neu))
--------------------------------------------------------------------------------
_________________
+++ Die beliebte QBasic CD-ROM von QBasic.de - 670 MB QBasic-Stuff mit komfortabler HTML-Oberfläche. Für nur 5 EUR bestellbar auf www.antonis.de/qbcdueb.htm +++ |
|
| Nach oben |
|
|
Armin_Graewe
Anmeldungsdatum: 13.03.2005
Beiträge: 14
Wohnort: Münster
|
| Verfasst am: 18.03.2005, 19:40 Titel: |
|
|
Hallo Freunde
habe mal eben ein ganz altes Prog von mir rausgekramt
da ist die "Fenster" (Rahmen)-Erstellung als SUB definiert
| Code: |
SUB makeframe (kopf$, o%, l%, u%, r%, rty%, cov%, coh%, rev%, fil%)
'Zeichnet einen Rahmen nach Vorgaben
'kopf$ = Name der Fensters
' o% = Position oberer Rand
' l% = Position linker Rand
' u% = Position unterer Rand
' r% = Position rechter Rand
'rty% = Rahmentyp 0=einfacher Rahmen, jeder andere Wert = Doppelrahmen
'cov% = Vordergrundfarbe
'coh% = Hintergrundfarbe
'rev% = 1=reverse Color, 0=normal color
'fil% = 1=Festerhintergrung mit Farbe mit Farbe fil% f?llen , 0=nicht gef?llt
IF rty% THEN
eol$ = CHR$(201)
eor$ = CHR$(187)
eul$ = CHR$(200)
eur$ = CHR$(188)
hlin% = 205
vlin% = 186
ELSE
eol$ = CHR$(218)
eor$ = CHR$(191)
eul$ = CHR$(192)
eur$ = CHR$(217)
hlin% = 196
vlin% = 179
END IF
COLOR cov%, coh%
LOCATE o%, l%: PRINT eol$; STRING$(r% - l% - 1, hlin%); eor$;
FOR x% = o% + 1 TO u% - 1
LOCATE x%, l%: PRINT CHR$(vlin%);
LOCATE x%, r%: PRINT CHR$(vlin%);
NEXT x%
LOCATE u%, l%: PRINT eul$; STRING$(r% - l% - 1, hlin%); eur$;
IF kopf$ <> "" THEN
xkopf$ = " " + kopf$ + " "
anf% = INT(r% - l% - LEN(xkopf$) - 1) / 2
IF rev% THEN
COLOR coh%, cov%
END IF
LOCATE o%, l% + anf% + 1: PRINT xkopf$;
IF rev% THEN
COLOR cov%, coh%
END IF
END IF
IF fil% THEN
COLOR cov%, fil%
FOR x% = o% + 1 TO u% - 1
LOCATE x%, l% + 1
PRINT STRING$(r% - l% - 1, 32)
NEXT x%
COLOR cov%, coh%
END IF
END SUB
|
ist nicht gerade elegant, aber geht 
Gruss
Armin
Der Hardwareverbieger |
|
| Nach oben |
|
|
Frosch
Anmeldungsdatum: 12.06.2005
Beiträge: 5
|
| Verfasst am: 12.06.2005, 00:22 Titel: |
|
|
Hallo,
ich bin neu hier, ich programmiere hobbymäßig bisher in PureBasic. Ich bin jetzt auf FreeBasic gestoßen. Grundsätzlich gefällt mir der Gedanke freier Software. Nachdem ich allerdings mitbekommen habe wie schwer es ist in FreeBasic GUI zu programmieren werde ich erst mal noch abwarten, wie sich FreeBasic weiter entwickelt.
Ich weiß nicht, ob es ok ist, wenn ich hier ein anderes Basic lobe, aber vielleicht kann ich damit ja jemandem helfen die für seine Zwecke passende Entwicklungsumgebung zu finden. Ich programmiere, wie schon gesagt in PureBasic, dort gibt es einen VisualDesigner, mit dem man seine Programmoberfläche ganz leicht gestalten kann (ohne Win API, also auch für Linux zu compilieren).
Ich hoffe das wird es in FreeBasic eines Tages auch alles geben, denn wie schon gesagt gefällt mir an FreeBasic, dass es freie Software ist.
Also bitte nicht böse sein, wegen der "Fremdwerbung".
Gruß Ralf |
|
| Nach oben |
|
|
Jojo
alter Rang
Anmeldungsdatum: 12.02.2005
Beiträge: 9736
Wohnort: Neben der Festplatte
|
| Verfasst am: 12.06.2005, 20:53 Titel: |
|
|
Von wegen Fremdwerbung
Über pureBasic wird hier auch öfter mal disktutiert
JetX wird sich hier wohl keinen Rat mehr einholen 
_________________
» Die Mathematik wurde geschaffen, um Probleme zu lösen, die es nicht gäbe, wenn die Mathematik nicht erschaffen worden wäre.
 |
|
| Nach oben |
|
|
Distelpalme
Anmeldungsdatum: 15.10.2004
Beiträge: 34
Wohnort: Basel
|
| Verfasst am: 12.06.2005, 22:45 Titel: ein rat |
|
|
ich hätt noch einen rat:
Probiers mal so:
Machst ein Fenster mit View und ziehst nen oberen rand mit X_[] (wenn du verstehst was gemeint ist) und dann packst du ne mausrouteine rein und machst ein paar boxen, und "spielst" die mausrouteine darauf "ab"
Dann kannst du noch, um es schön zu machen, den oberen balken klick&drag fähig machen, dass du das fenster verschieben kannst.
viel spaß  |
|
| Nach oben |
|
|
Stephan
Anmeldungsdatum: 05.10.2004
Beiträge: 358
Wohnort: Hessen - 20km Nördlich von Frankfurt am Main
|
| Verfasst am: 12.06.2005, 23:46 Titel: |
|
|
Dieses thema hat sich doch eigentlich schon länger erledigt, warum wird hier eigentlich noch geantwortet ?
_________________
'Wir schätzen die Zeit erst, wenn uns nicht mehr viel davon geblieben ist.'
Leo Tolstoi |
|
| Nach oben |
|
|
Frosch
Anmeldungsdatum: 12.06.2005
Beiträge: 5
|
| Verfasst am: 12.06.2005, 23:49 Titel: |
|
|
@Stephan,
sorry, das wußt ich nicht. Ich bin neu hier im Forum und irgendwie zufällig auf diesen Tread gestoßen, weil ich nach GUI gesucht habe.
Ich finde es nett, dass man mir geantwortet hat.
Gruß Ralf |
|
| Nach oben |
|
|
Jojo
alter Rang
Anmeldungsdatum: 12.02.2005
Beiträge: 9736
Wohnort: Neben der Festplatte
|
| Verfasst am: 13.06.2005, 20:41 Titel: |
|
|
@Stephan: Wir ham uns gar net auf JetX sondern auf Frosch bezogen
_________________
» Die Mathematik wurde geschaffen, um Probleme zu lösen, die es nicht gäbe, wenn die Mathematik nicht erschaffen worden wäre.
|
|
| Nach oben |
|
|
Dusky_Joe
Anmeldungsdatum: 07.01.2005
Beiträge: 1007
Wohnort: Regensburg/Oberpfalz
|
| Verfasst am: 14.06.2005, 16:41 Titel: |
|
|
Kurz noch zum Thema Win-GUI in freeBASIC: ich schreibe zurzeit an einem Tutorial, das dieses Thema behandelt.
Zwei Kapitel sind schon fertig, eines ist in Arbeit (~70%).
Link:
http://dhost.info/siteofkaos/freeBASIC/WIN-GUI-Grundlagen.html
Diese Datei wird dort so lange liegen, bis Mecki auf seiner Seite (www.freebasic.de) das Tut online stellt - da fällt mir ein: Ich muss mal sehen, ob er das schon getan hat
_________________
fully biological degradable
Once, the big wave arrives, you've got two ways, you can go:
Either, you ride it, or you don't do.
But, if you don't ride, you'll never know wether you'd have gone wet. |
|
| Nach oben |
|
|
|
|
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
|
|
FAQ
Suchen
Mitgliederliste
Benutzergruppen
Registrieren
Profil
Einloggen, um private Nachrichten zu lesen
Login
