 |
Das deutsche QBasic- und FreeBASIC-Forum
Für euch erreichbar unter qb-forum.de, fb-forum.de und freebasic-forum.de!
|
| Vorheriges Thema anzeigen :: Nächstes Thema anzeigen |
| Autor |
Nachricht |
croco97
Anmeldungsdatum: 04.11.2005
Beiträge: 260
|
 Verfasst am: 06.01.2009, 14:52 Titel: [Gelöst] Problem mit Konstruktoren |
 |
|
Hi zusammen!
2 Fragen, die sich darum drehen, wenn man quasi eine Klasse aus einer anderen ableitet im Sinne von
| Code: |
type tfoo
(...)
end type
type tfoo2
foo as tfoo
(...)
end type
|
1.) Wie rufe ich explizit Destruktoren auf?
Die Frage stellt sich, wenn tfoo einen expliziten Destruktor hat, der vom Destruktor tfoo2 aufgerufen werden muss. Geschieht das automatisch? Geschieht das auch dann automatisch, wenn tfoo2 einen expliziten Destruktor hat?
2.) Ich alloziiere innerhalb von tfoo mit ALLOCATE einen Filebuffer buf=allocate(recsize*bufsize). Und gebe ihn mit deallocate im Destruktor wieder frei. Klappt gut und robust. Solange ich nicht tfoo nach tfoo2 einbette. Will ich anschliessend buf vom Konstruktor von tfoo2 aufrufen, ist die Adresse von buf zwar OK, aber der Zugriff geht daneben. Hier ein Beispiel-Code:
| Code: |
' Problem mit Allokationen in Konstruktoren
' FBC Ver. 020
const recsize=100000
type tfoo
buf as zstring ptr
declare constructor()
declare constructor(bufsize0 as integer)
declare destructor()
end type
type tfoo2
foo as tfoo
declare constructor(bufsize0 as integer)
end type
constructor tfoo()
end constructor
destructor tfoo()
deallocate buf
end destructor
constructor tfoo(bufsize0 as integer)
buf=allocate(bufsize0*recsize)
? buf
end constructor
constructor tfoo2(bufsize0 as integer)
dim i as integer
foo=tfoo(bufsize0)
for i=0 to 9990
? i,foo.buf
foo.buf[i*recsize]="Test Test Test Test Test Test Test Test Test Test Test Test "
'==> Hier knallt's
next i
end constructor
dim as tfoo2 foo2=tfoo2(100000)
|
Hat jemand eine Erklärung?
Nebenbemerkung:
Hier fehlt die Freigabe, weil das Problem ja schon beim Konstruktor auftaucht.
Vielen Dank schon mal und viele Grüsse!
Croco
Zuletzt bearbeitet von croco97 am 08.01.2009, 11:42, insgesamt einmal bearbeitet |
|
| Nach oben |
|
 |
Jojo
alter Rang
Anmeldungsdatum: 12.02.2005
Beiträge: 9736
Wohnort: Neben der Festplatte
|
| Verfasst am: 06.01.2009, 15:50 Titel: |
|
|
ich hoffe mal, ich hab deine erste frage jetzt richtig verstanden...
selber aufrufen kannst du destruktoren glaub ich nicht (deswegen schreibe ich mir in so einem fall eine zusätzliche sub, die ich auch von außen aufrufen kann und die der destructor aufruft), aber sofern du das programm nicht mit END abwürgst, werden die destruktoren immer aufgerufen
_________________
» Die Mathematik wurde geschaffen, um Probleme zu lösen, die es nicht gäbe, wenn die Mathematik nicht erschaffen worden wäre.
 |
|
| Nach oben |
|
|
ThePuppetMaster
Anmeldungsdatum: 18.02.2007
Beiträge: 1839
Wohnort: [JN58JR]
|
| Verfasst am: 06.01.2009, 15:52 Titel: |
|
|
Auch mit "End" wird der destructor aufgerufen.
MfG
TPM
_________________
[ WebFBC ][ OPS ][ ToOFlo ][ Wiemann.TV ] |
|
| Nach oben |
|
|
Jojo
alter Rang
Anmeldungsdatum: 12.02.2005
Beiträge: 9736
Wohnort: Neben der Festplatte
|
| Verfasst am: 06.01.2009, 15:55 Titel: |
|
|
nein, nur modul-destruktoren werden aufgerufen, aber nicht die destructoren von TYPEs.
_________________
» Die Mathematik wurde geschaffen, um Probleme zu lösen, die es nicht gäbe, wenn die Mathematik nicht erschaffen worden wäre.
|
|
| Nach oben |
|
|
croco97
Anmeldungsdatum: 04.11.2005
Beiträge: 260
|
| Verfasst am: 06.01.2009, 18:11 Titel: |
|
|
@Jojo: Ja, du hast die Frage verstanden. Die Umgehung mit einer eigenen Destruktoren-Methode ist eher unschön. Muss mal schauen, was ich über die Destruktoren noch herausfinde...
Habe inzwischen neue Erkenntnisse bzgl. Frage 2: Der Grund für die Speicherverletzung liegt darin, dass unmittelbar nach dem Konstruktor von tfoo der Destruktor von tfoo aufgerufen wird. Allerdings habe ich keine Ahnung, warum. Sehr seltsam. Vielleicht hat einer von Euch ne gute Idee...
VG!
Croco |
|
| Nach oben |
|
|
volta
Anmeldungsdatum: 04.05.2005
Beiträge: 1876
Wohnort: D59192
|
| Verfasst am: 07.01.2009, 18:27 Titel: |
|
|
Hi,
ich vermute den Grund für die Speicherverletzung in | Code: | | foo.buf[i*recsize]="Test ... |
da bei i=5000 auch 2GB Speicher überschritten werden (5000*100000*4).
Bei mir fährt das Prog schon bei | Code: | | buf=allocate(bufsize0*recsize) |
an die Wand (die angeforderten 9,3GB können wohl nicht geliefert werden). 
Der Aufruf des Destruktors erklärt sich daraus, dass mit zwar tfoo aufgerufen wird (also Konstruktor abarbeiten) aber keine UDT-Variable dauerhaft gebildet wird (also sofort Destruktor abarbeiten).
Ich habe mal einen Destruktor in foo2 eingebaut und mir das Asm-Listing angesehen----> | Code: | lea eax, [ebp-8]
push eax
call __ZN5TFOO2D1Ev '<-- Destruktor von foo2
add esp, 4
push 0
call _fb_End@4
mov eax, dword ptr [ebp-4]
mov esp, ebp
pop ebp
ret |
EDIT\ es ist doch komplizierter als ich dachte 
@Jojo hat Recht, bei END wird abgewürgt. | Code: | push -1
call _fb_Sleep@4 'SLEEP
push 0
call _fb_End@4 'END
'Hier ist Schluß Dieser Teil wird nicht mehr ausgeführt!!
push 1 'PRINT "Ende"
push 5
push offset _Lt_001E
call _fb_StrAllocTempDescZEx@8
push eax
push 0
call _fb_PrintString@12
lea eax, [ebp-8]
lea eax, [ebp-8]
push eax 'also auch kein Destruktor vom foo2
call __ZN5TFOO2D1Ev
add esp, 4
push 0
call _fb_End@4
mov eax, dword ptr [ebp-4]
mov esp, ebp
pop ebp
ret |
_________________
Warnung an Choleriker:
Dieser Beitrag kann Spuren von Ironie & Sarkasmus enthalten.
Zu Risiken & Nebenwirkungen fragen Sie Ihren Therapeuten oder Psychiater. |
|
| Nach oben |
|
|
croco97
Anmeldungsdatum: 04.11.2005
Beiträge: 260
|
| Verfasst am: 08.01.2009, 10:32 Titel: |
|
|
| volta hat Folgendes geschrieben: | Hi,
ich vermute den Grund für die Speicherverletzung in | Code: | | foo.buf[i*recsize]="Test ... |
da bei i=5000 auch 2GB Speicher überschritten werden (5000*100000*4).
|
Meine Güte, wie degeneriert bin ich schon, dass ich sowas nicht mehr nachrechne? Früher hat man sich bei jedem Array Gedanken darüber gemacht, ob es die 8K maximale Stack Size (Turbo C++ für DOS) überschreitet ...
Allerdings liegt das Hauptproblem woanders, wie ich inzwischen rausgefunden habe. Es sollte ja grundsätzlich bei Objekten genauso wie bei anderen Variablen die Möglichkeit geben, statisch oder dynamisch zu deklarieren, also
oder
| Code: |
dim as mytype ptr x
x=new mytype
|
Well, ich habe keine Dokumentation gefunden, wie man Konstruktoren von statisch deklarierten Objekten aufruft, wenn man dort Parameter braucht. Der Aufruf
foo=tfoo(Parameter) wird zwar syntaktisch nicht beanstandet, ist aber, wie ich jetzt rausgefunden habe, was ganz anderes, nämlich die Verwendung eines temporären type. Kein Wunder, dass da sofort der Destruktor aufgerufen wird ...
Die Frage bleibt: Sieht FB bei statischen Klassen parametrisierte Konstruktoren gar nicht vor? Oder hab ich die Syntax nur nicht gefunden?
Der Workaround ist einfach und relativ unproblematisch: Man bastelt seine eigene init-Routine und verwendet sie als Konstruktor - parametrisierte Konstruktoren werden ohnehin nicht automatisch aufgerufen. Und den Vorzug des automatischen Destruktoraufrufs geniesst man dann immer noch.
VG!
Croco |
|
| Nach oben |
|
|
nemored
Anmeldungsdatum: 22.02.2007
Beiträge: 4699
Wohnort: ~/
|
| Verfasst am: 08.01.2009, 16:17 Titel: |
|
|
Weiß jetzt nicht, ob ich das richtig verstanden habe ...
| Zitat: | Well, ich habe keine Dokumentation gefunden, wie man Konstruktoren von statisch deklarierten Objekten aufruft, wenn man dort Parameter braucht. Der Aufruf
foo=tfoo(Parameter) wird zwar syntaktisch nicht beanstandet, ist aber, wie ich jetzt rausgefunden habe, was ganz anderes, nämlich die Verwendung eines temporären type. |
hängt doch davon ab, wo foo deklariert wird? Folgendes funktioniert genau so, wie ich es erwarte:
| Code: | type tfoo
as byte x, y
declare constructor(xwert as byte = 0, ywert as byte = 0)
declare destructor
end type
constructor tfoo(xwert as byte = 0, ywert as byte = 0)
this.x = xwert
this.y = ywert
print "Initialisiere eine tfoo-Variable mit den Werten " & xwert & " / " & ywert
end constructor
destructor tfoo
print "tfoo-Variable wurde zerstoert!"
end destructor
sub footest
static foo as tfoo = tfoo(3, 4)
foo.y +=1
print "foo ist jetzt " & foo.x & " / " & foo.y
end sub
for i as ubyte = 1 to 5
print i & ". Aufruf von footest: ";
footest
next
' Programmende; jetzt wird der DESTRUCTOR aufgerufen |
_________________
Deine Chance beträgt 1:1000. Also musst du folgendes tun: Vergiss die 1000 und konzentriere dich auf die 1. |
|
| Nach oben |
|
|
croco97
Anmeldungsdatum: 04.11.2005
Beiträge: 260
|
| Verfasst am: 08.01.2009, 17:55 Titel: |
|
|
| nemored hat Folgendes geschrieben: | Weiß jetzt nicht, ob ich das richtig verstanden habe ...
|
| Code: |
type tfoo
as byte x, y
declare constructor(xwert as byte = 0, ywert as byte = 0)
declare destructor
end type
constructor tfoo(xwert as byte = 0, ywert as byte = 0)
(...)
sub footest
static foo as tfoo = tfoo(3, 4)
(...)
end sub
|
Hier konstruierst du foo nicht als Eigenschaft einer Klasse, sondern als "normale" Variable. Ich kann ja schlecht
| Code: |
type tfoo2
foo as tfoo=tfoo(...)
end type
|
schreiben...
Viele Grüsse!
Croco |
|
| Nach oben |
|
|
nemored
Anmeldungsdatum: 22.02.2007
Beiträge: 4699
Wohnort: ~/
|
| Verfasst am: 08.01.2009, 18:44 Titel: |
|
|
Mal ganz böse getrickst:
| Code: | type tfoo1
as byte x, y, lokal
declare constructor(xwert as byte = 0, ywert as byte = 0, lokal as byte = 0)
declare destructor
end type
type tfoo2
as tfoo1 xy
declare constructor
declare destructor
end type
constructor tfoo1(xwert as byte = 0, ywert as byte = 0, lokal as byte = 0)
this.x = xwert
this.y = ywert
this.lokal = lokal
if lokal = 0 then
print "Initialisiere eine tfoo1-Variable mit den Werten " & xwert & " / " & ywert
else
print "(Initialisierung einer lokalen tfoo1-Variablen)"
end if
end constructor
destructor tfoo1
if this.lokal = 0 then
print "tfoo1-Variable wurde zerstoert!"
else
print "(Zerstoerung einer lokalen Instanz)"
end if
end destructor
constructor tfoo2
this.xy = tfoo1(1, 2, -1)
this.xy.lokal = 0
print "Initialisiere eine tfoo2-Variable"
end constructor
destructor tfoo2
print "tfoo2-Variable wurde zerstoert!"
end destructor
dim as tfoo2 foo
print "foo.xy hat den Wert " & foo.xy.x & " / " & foo.xy.y
getkey
' Programmende; jetzt wird der DESTRUCTOR aufgerufen |
Mein Programm soll sich also merken, ob die initialisierte Variable nur mal eben kurz lokal erzeugt wurde oder global Bedeutung hat. Nur im zweiten Fall werden dann die entsprechenden Operationen ausgeführt. Vielleicht klappt's ja ...
_________________
Deine Chance beträgt 1:1000. Also musst du folgendes tun: Vergiss die 1000 und konzentriere dich auf die 1. |
|
| Nach oben |
|
|
croco97
Anmeldungsdatum: 04.11.2005
Beiträge: 260
|
| Verfasst am: 10.01.2009, 16:30 Titel: |
|
|
| nemored hat Folgendes geschrieben: | Mal ganz böse getrickst:
|
Oh, das klappt ja überraschend gut. Ich hatte auch erst so einen "Bastel"-Gedanken, bin aber wieder davon abgekommen, ihn auszuprobieren, weil ich meinte, da ein Wirrwar in den Destruktorenaufruf reinzubringen. Aber bei näherem Nachdenken und Anschauen deines Codes:
Die Besetzung der Eigenschaften von xy läuft korrekt und im ersten Destruktor wird das Anfassen der Zeiger vermieden (Bereich "lokale Instanz" wird angesteuert.)
Aber am Ende wird nochmal tatsächlich der "richtige" Destruktor aufgerufen. Müsste also soweit ziemlich allgemein und ohne Seiteneffekte anwendbar sein.
Freilich: An der Sprachkonstruktion ist noch was nicht ganz korrekt, wenn solche Klimmzüge notwendig werden, um bestimmte parametrisierte Konstruktoren aufzurufen. Sollte man vielleicht mal auf freebasic.net posten.
VG!
Croco |
|
| Nach oben |
|
|
|
|
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
|
|
FAQ
Suchen
Mitgliederliste
Benutzergruppen
Registrieren
Profil
Einloggen, um private Nachrichten zu lesen
Login
