Das deutsche QBasic- und FreeBASIC-Forum Foren-Übersicht Das deutsche QBasic- und FreeBASIC-Forum
Für euch erreichbar unter qb-forum.de, fb-forum.de und freebasic-forum.de!
 
FAQFAQ   SuchenSuchen   MitgliederlisteMitgliederliste   BenutzergruppenBenutzergruppen  RegistrierenRegistrieren
ProfilProfil   Einloggen, um private Nachrichten zu lesenEinloggen, um private Nachrichten zu lesen   LoginLogin
Zur Begleitseite des Forums / Chat / Impressum
Aktueller Forenpartner:

Nochmal UDP-Server :(

 
Neues Thema eröffnen   Neue Antwort erstellen    Das deutsche QBasic- und FreeBASIC-Forum Foren-Übersicht -> Allgemeine Fragen zu FreeBASIC.
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen  
Autor Nachricht
pb



Anmeldungsdatum: 10.08.2020
Beiträge: 8

BeitragVerfasst am: 11.08.2020, 14:50    Titel: Nochmal UDP-Server :( Antworten mit Zitat

Hallo nochmal - ich habe das untenstehende Programm gefunden es wäre genau was ich brauche - leider bekomme ich nur Fehlermeldungen angezeigt - chisock ist wohl schon ein bischen alt traurig
Wenn ich so einen Ansatz hätte könnte ich mein Programm fertigschreiben. Gibt es das vielleicht auch für die TSNE_V3.bi? Ich brauche nur einen kleinen UDP-Server um meine Messdaten empfangen zu können - sorry aber Netzwerkprogrammierung ist halt mal nicht so meine Stärke!!

Code:
#Include "chisock/chisock.bi"
Using chi

Dim UdpServer As Socket
Dim DataInput As String
Dim DataOutput As String
UdpServer.UDP_Server(1337)

Do
   DataOutput = InKey()
   If DataOutput <> "" Then
      UdpServer.Put(DataOutput)
   EndIf
   If UdpServer.Get(DataInput) Then
      Print DataInput
   EndIf
Loop Until MultiKey(1)

UdpServer.Close()
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
grindstone



Anmeldungsdatum: 03.10.2010
Beiträge: 1208
Wohnort: Ruhrpott

BeitragVerfasst am: 11.08.2020, 16:09    Titel: Antworten mit Zitat

Hallo,

so ganz auf die Schnelle habe ich bei mir das hier gefunden. Vielleicht kannst du ja was damit anfangen:
Code:
'##############################################################################################################
'TEST-CLIENT für TSNE_V3 [UDP]
'##############################################################################################################



'##############################################################################################################
#include once "TSNE_V3.bi"                     'Die TCP Netzwerkbibliotek integrieren



'##############################################################################################################
Dim G_ClientRX as UInteger                     'Eine Variable für den Client-Handel erstellen
Dim G_ClientTX as UInteger                     'Eine Variable für den Client-Handel erstellen



'##############################################################################################################
'   Deklarationen für die Empfänger Sub Routinen erstellen
'   Nur dann nötig, wenn die Sub's unterhalb des aufrufs stehen.
Declare Sub   TSNE_NewDataUDP      (ByVal V_TSNEID as UInteger, ByVal V_IPA as String, ByRef V_Data as String)



'##############################################################################################################
Print "[INIT] Client..."                     'Programm beginnen
Dim BV as Integer                           'Variable für Statusrückgabe erstellen


Print "[Create UDP]"
BV = TSNE_Create_UDP_TX(G_ClientTX)               'UDP-Socket zum senden erstellen
'   Statusrückgabe auswerten
If BV <> TSNE_Const_NoError Then
   Print "[FEHLER] " & TSNE_GetGURUCode(BV)      'Fehler ausgeben
   End -1                                 'Programmbeenden
End If


BV = TSNE_Create_UDP_RX(G_ClientRX, 1234, @TSNE_NewDataUDP)      'UDP-Socket für den Empfang erstellen
'   Statusrückgabe auswerten
If BV <> TSNE_Const_NoError Then
   Print "[FEHLER] " & TSNE_GetGURUCode(BV)      'Fehler ausgeben
   End -1                                 'Programmbeenden
End If


Print "[OK]"                              'Verbindung wurde erfolgreich hergestellt.


Do until inkey() = Chr(27)
   Print "Send"
   
   'Um Daten zu senden muss [NUR im UDP Modus] eine IP Adresse und ein Port angegeben werden.
   'Wird als IP-Adresse "0" angegeben wird die nachricht als Broadcast an alle im Subnetz vorhandenen
   'Clienten gesendet.
   BV = TSNE_Data_Send(G_ClientTX, Str(Timer()), , "localhost", 1234)      'Senden an DIREKT an sich selbst
'   BV = TSNE_Data_Send(G_ClientTX, Str(Timer()), , "0", 1234)            'Sendet an ALLE im Subnetz
   If BV <> TSNE_Const_NoError Then
      Print "[FEHLER] " & TSNE_GetGURUCode(BV)   'Fehler ausgeben
      End -1                              'Programmbeenden
   End If
   sleep 1000, 1                           'Im Sekundenabstand senden
Loop



TSNE_Disconnect(G_ClientTX)                     'UDP-Socket wieder schliessen
TSNE_Disconnect(G_ClientRX)                     'UDP-Socket wieder schliessen
Print "[WAIT] ..."                           'Warte auf das ende der Verbindung (Disconnect)
TSNE_WaitClose(G_ClientTX)
TSNE_WaitClose(G_ClientRX)
Print "[WAIT] OK"


Print "[END]"
End                                       'Anschliessend beenden wir unser Programm



'##############################################################################################################
Sub TSNE_NewDataUDP (ByVal V_TSNEID as UInteger, ByVal V_IPA as String, ByRef V_Data as String)   'Empfänger für neue Daten (UDP)
'Beim UDP-Modus wird nicht nur die empfangenen Daten, sondern auch die IP des senders übergeben.
Print "[NDA]: >" & V_IPA & "<___>" & V_Data & "<"
End Sub




Gruß
grindstone
_________________
For ein halbes Jahr wuste ich nich mahl wie man Proggramira schreibt. Jetzt bin ich einen!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden E-Mail senden
pb



Anmeldungsdatum: 10.08.2020
Beiträge: 8

BeitragVerfasst am: 12.08.2020, 12:56    Titel: Antworten mit Zitat

Hallo grindstone...das war es was ich suchte...funktioniert wie es soll!!!! Herzlichen Dank!!!!!
Nach oben
Benutzer-Profile anzeigen Private Nachricht senden
Beiträge der letzten Zeit anzeigen:   
Neues Thema eröffnen   Neue Antwort erstellen    Das deutsche QBasic- und FreeBASIC-Forum Foren-Übersicht -> Allgemeine Fragen zu FreeBASIC. Alle Zeiten sind GMT + 1 Stunde
Seite 1 von 1

 
Gehe zu:  
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.

 Impressum :: Datenschutz