|
Das deutsche QBasic- und FreeBASIC-Forum Für euch erreichbar unter qb-forum.de, fb-forum.de und freebasic-forum.de!
|
Vorheriges Thema anzeigen :: Nächstes Thema anzeigen |
Autor |
Nachricht |
Elor
Anmeldungsdatum: 12.07.2013 Beiträge: 205 Wohnort: Konstanz
|
Verfasst am: 29.06.2016, 11:10 Titel: Mehrdimensionales Pointer Arrays |
|
|
Wenn ich ein Zeiger-Array erstellen möchte, mach ich folgendes:
Code: |
Dim PArray As Integer Ptr
PArray= Callocate (3* SizeOf (Integer))
PArray[0]= 1
…
|
Das Funktioniert ja auch, aber wenn ich ein zweidimensionales Array erstelle und zwar so
Code: |
Dim PArray As Integer Ptr Ptr
PArray= Callocate (3* 3* SizeOf (Integer))
PArray[0][0]= 1
…
|
Übersetzen tut der Compiler das, aber zur Laufzeit gibt es einen Crash! Sowohl mit dem Linux 64Bit Compiler als auch unter Windows 10(32). Wo liegt da mein Denkfehler? |
|
Nach oben |
|
|
St_W
Anmeldungsdatum: 22.07.2007 Beiträge: 949 Wohnort: Austria
|
Verfasst am: 29.06.2016, 12:22 Titel: |
|
|
Naja es handelt sich bei deinem Array schlicht um keinen Integer ptr ptr.
Skizze:
Code: | +----+ PArray[0][0]
PArray[0] +------> | | +-------------> ????
+----+
| |
+----+
| |
+----+
|
Die zweite Pointer Derefernzierung führt dann ins Nirvana. _________________ Aktuelle FreeBasic Builds, Projekte, Code-Snippets unter http://users.freebasic-portal.de/stw/
http://www.mv-lacken.at Musikverein Lacken (MV Lacken) |
|
Nach oben |
|
|
Elor
Anmeldungsdatum: 12.07.2013 Beiträge: 205 Wohnort: Konstanz
|
Verfasst am: 29.06.2016, 14:27 Titel: |
|
|
Ja stimmt, es ist kein Array im eigentlichen sinne. Es ist nur eine Speicherreservierung für eine bestimmte Anzahl Byte. Aber ehrlich gesagt steh ich Grad Ziemlich auf dem Schlauch was die Deklaration und Initialisierung für einen Mehrdimensionalen zugriff angeht.
Ich möchte aus einer Datei Arrays einlesen deren Dimensionen unterschiedlich groß sind. Kannst du mir mal auf die Sprünge helfen? |
|
Nach oben |
|
|
nemored
Anmeldungsdatum: 22.02.2007 Beiträge: 4597 Wohnort: ~/
|
Verfasst am: 29.06.2016, 15:06 Titel: |
|
|
FreeBASIC verwaltet seine eigenen Arrays ganz einfach so, dass die einzelnen "Reihen" hintereinandergeschalten werden.
Code: | dim as integer a(9, 19)
dim as integer ptr aptr = @a(0, 0)
for i as integer = 0 to 9
for k as integer = 0 to 19
a(i, k) = int(rnd*9999)
next
next
print a(2, 5)
print aptr[20*2 + 5] |
Die Dimensionen müssen dazu allerdings bekannt sein oder gesondert gespeichert werden. _________________ Deine Chance beträgt 1:1000. Also musst du folgendes tun: Vergiss die 1000 und konzentriere dich auf die 1. |
|
Nach oben |
|
|
Elor
Anmeldungsdatum: 12.07.2013 Beiträge: 205 Wohnort: Konstanz
|
Verfasst am: 29.06.2016, 21:50 Titel: |
|
|
Hmm... ich glaub ich muss mal genauer erklären was ich meine. Die Anzahl der Dimensionen wird aus einer Textdatei, gefolgt von den Dimension Größen und Daten, gelesen. Sie ist also bei Programmstart noch nicht bekannt. Ein Beispiel für die Text Datei:
[ARRAY1]
2 3 3
hier stehen die Daten
[ARRAY2]
3 4 4 4
Daten …
Die erste Zahl ist die Anzahl der Dimensionen gefolgt von der Dimension Größe. Das entspräche ja der Deklaration:
Code: |
Dim Array1(0 To 2, 0 To 2) As DatenType
Dim Array2(0 To 3, 0 To 3, 0 To 3) As DatenType
|
Da ich die Anzahl der Dims nicht kenne, muss ich die so
Code: |
ReDim Array1() As DatenType
|
Deklarieren.
Ich hab eine SUB, die nach Prüfung ob Datei und Array existiert, die Dimension einliest. Diesen wert werte ich mit CASE aus, erzeuge das Array mit ReDim () und lies die Daten ein. Der Aufruf sieht so aus:
Code: |
LoadArray (DateiName, ArrayName, Array())
|
Ich hab mich gefragt ob die CASE Auswertung irgend wie durch eine Pointer Variante ersetzt werden kann. Kann man? Und wie müsste das aussehen?
Edit: Ich meine natürlich nicht nur das ersetzen der CASE, sondern auch die ReDim! |
|
Nach oben |
|
|
nemored
Anmeldungsdatum: 22.02.2007 Beiträge: 4597 Wohnort: ~/
|
Verfasst am: 29.06.2016, 22:52 Titel: |
|
|
Du kannst da selbstverständlich mit Pointern arbeiten, und zwar genau nach dem von mir vorgeschlagenen System. Wenn du ein Array arr(0 to d1, 0 to d2, 0 to d3, 0 to d4) einrichten willst, dann liegt der Eintrag arr(a1, a2, a3, a4) an der Stelle
Code: | arr[a1*(d2+1)*(d3+1)*(d4+1) + a2*(d3+1)*(d4+1) + a3*(d4+1) + d4] |
Code: | dim as integer d1 = 7, d2 = 3, d3 = 6, d4 = 12
dim as integer a1 = 3, a2 = 1, a3 = 3, a4 = 5
dim as integer arr(0 to d1, 0 to d2, 0 to d3, 0 to d4)
arr(a1, a2, a3, a4) = 7331
dim as integer ptr arrptr = @arr(0, 0, 0, 0)
print arrptr[a1*(d2+1)*(d3+1)*(d4+1) + a2*(d3+1)*(d4+1) + a3*(d4+1) + a4] |
Ich habe da mal nur den FreeBASIC-Aufbau nachgebaut, du kannst natürlich die Elemente direkt in einen (C)ALLOCATE-Speicher schreiben und daraus lesen. Wenn du eine maximale Dimensionenzahl hast, ist alles gut - nicht vorhandene Dimensionen laufen dann halt einfach von 0 TO 0. (Bei beliebigen Dimensionenzahlen müsste man das dann halt dynamisieren.)
===================
edit: Ich habe mal schnell einen kleinen Array-TYPE gebastelt; der soll aber nur zu Demonstrationszwecken dienen und nicht als Musterbeispiel. Abgesehen davon, dass er keine Sicherheitsabfragen für falschen Zugriff enthält, ist er auch alles andere als optimiert.
Code: | type TArray
' Integer-Array mit Maximallaenge 8
dim as integer ptr arrPtr
dim as integer dimension(7)
dim as integer startpos(7)
declare constructor
declare constructor(d0 as integer, d1 as integer = 0, d2 as integer = 0, d3 as integer = 0, _
d4 as integer = 0, d5 as integer = 0, d6 as integer = 0, d7 as integer = 0)
declare destructor
declare function get(d0 as integer, d1 as integer = 0, d2 as integer = 0, d3 as integer = 0, _
d4 as integer = 0, d5 as integer = 0, d6 as integer = 0, d7 as integer = 0) as integer
declare sub set(value as integer, d0 as integer, d1 as integer = 0, d2 as integer = 0, d3 as integer = 0, _
d4 as integer = 0, d5 as integer = 0, d6 as integer = 0, d7 as integer = 0)
end type
constructor TArray
end constructor
constructor TArray(d0 as integer, d1 as integer = 0, d2 as integer = 0, d3 as integer = 0, _
d4 as integer = 0, d5 as integer = 0, d6 as integer = 0, d7 as integer = 0)
if arrPtr then deallocate arrPtr
arrPtr = callocate((d0+1)*(d1+1)*(d2+1)*(d3+1)*(d4+1)*(d5+1)*(d6+1)*(d7+1))
startpos(7) = 0
startpos(6) = d7+1
startpos(5) = startpos(6)*(d6+1)
startpos(4) = startpos(5)*(d5+1)
startpos(3) = startpos(4)*(d4+1)
startpos(2) = startpos(3)*(d3+1)
startpos(1) = startpos(2)*(d2+1)
startpos(0) = startpos(1)*(d1+1)
end constructor
destructor TArray
deallocate arrPtr
arrPtr = 0
end destructor
function TArray.get(d0 as integer, d1 as integer = 0, d2 as integer = 0, d3 as integer = 0, _
d4 as integer = 0, d5 as integer = 0, d6 as integer = 0, d7 as integer = 0) as integer
return this.arrPtr[d0*startpos(0) + d1*startpos(1) + d2*startpos(2) + d3*startpos(3) _
+ d4*startpos(4) + d5*startpos(5) + d6*startpos(6) + d7*startpos(7)]
end function
sub TArray.set(value as integer, d0 as integer, d1 as integer = 0, d2 as integer = 0, d3 as integer = 0, _
d4 as integer = 0, d5 as integer = 0, d6 as integer = 0, d7 as integer = 0)
arrPtr[d0*startpos(0) + d1*startpos(1) + d2*startpos(2) + d3*startpos(3) _
+ d4*startpos(4) + d5*startpos(5) + d6*startpos(6) + d7*startpos(7)] = value
end sub
' vvv BEDIENUNGSBEISPIEL vvv
dim as TArray ptr arr = new TArray(3, 4, 5) ' Array(0 TO 3, 0 TO 4, 0 TO 5)
arr->set(7331, 2, 2, 3) ' Array(2, 2, 3) = 7331
print arr->get(2, 2, 3) ' PRINT Array (2, 2, 3)
delete arr |
_________________ Deine Chance beträgt 1:1000. Also musst du folgendes tun: Vergiss die 1000 und konzentriere dich auf die 1. |
|
Nach oben |
|
|
Elor
Anmeldungsdatum: 12.07.2013 Beiträge: 205 Wohnort: Konstanz
|
Verfasst am: 30.06.2016, 12:50 Titel: |
|
|
Erst mal vielen dank für eure antworten! Ich hab mir das ganze jetzt noch mal genau durch den Kopf gehen lassen und kam dabei zu folgendem Schluss... so wie ich mir das vorgestellt hab Funktioniert es nicht! Ich hatte nämlich nicht berücksichtigt, dass ich zur weiter Verarbeitung die Anzahl der Dimensionen und deren Größe noch brauche. Die Dinger müsste ich also Explizit mit herum schleifen. Außerdem existieren die Array Namen nur in der Textdatei und im Aufruf der SUB, aber nie als Variable im Programm. Aber egal ob ich die REDIM oder PTR Variante nehme, um die Auswertung der Dimensionen und deren Größe komme ich nicht herum. Ich brauch aber zum einlesen der Daten je Dimension eine FOR Schleife, die Verschachtelung nimmt also pro Dimension zu.
@nemored: Nach dem ich mit deinem Beispiel herum gespielt hab, kam ich auf die Idee, die Daten in einen Buffer einzulesen. In der CASE Selektion brauch ich jetzt nur noch entsprechend zu Redimensionieren und Kopiere am Schluss die Daten vom Buffer in das Array. Lange rede kurzer Sinn, hier mal meine vorläufige lösung.
Code: |
#include Once "file.bi" /' FileExists '/
#include Once "crt/string.bi" /' wegen MemCpy '/
Declare Sub LoadArray (ByRef FileName As String, ByRef SecName As String, Array() As Single)
ReDim aArray() As Single
LoadArray ("data.txt", "array2", aArray())
Print "--------------------------------------------------------------------"
/' Hier die Annahme das es sich um ein 2 Dimensionales Arraya handelt '/
For Y As Integer= lBound (aArray, 1) To uBound (aArray, 1)
For X As Integer= lBound (aArray, 2) To uBound (aArray, 2)
Print aArray(Y, X),
Next X
Print
Next Y
Print "--------------------------------------------------------------------"
Erase (aArray) '' kann man sich an dieser stelle auch sparen
Sub LoadArray (ByRef FileName As String, ByRef SecName As String, Array() As Single)
Dim As Integer Dimension, Counter= 1, hFile
ReDim As Integer Size()
Dim As Single Ptr Buffer
Dim As String SecStr, sBuf
If FileExists (FileName) Then
SecStr= "["& uCase (SecName)& "]"
hFile= FreeFile ()
Open FileName For InPut As hFile
/' Array Sektion suchen '/
While Not Eof (hFile)
Line InPut #hFile, sBuf
If(uCase (sBuf) = SecStr) Then Exit While
Wend
If(uCase (sBuf) = SecStr) Then /' Sektion gefunden? '/
InPut #hFile, Dimension
ReDim Size(Dimension- 1)
For I As Integer= 0 To Dimension- 1
InPut #hFile, Size(I)
Counter= Counter* Size(I)
Next I
Buffer= Allocate (Counter* SizeOf (Single))
For I As Integer= 0 To Counter- 1
InPut #hFile, Buffer[I]
Next I
Select Case Dimension
Case 1: ''
ReDim Array(Size(0)- 1)
Case 2:
ReDim Array(Size(0)- 1, Size(1)- 1)
/' ... usw ... '/
End Select
/' wenn alles geklappt hat... '/
MemCpy (@Array(0), Buffer, Counter* SizeOf (Single))
DeAllocate (Buffer) /' wird nicht mehr gebraucht! '/
End If
Close (hFile)
End If
End Sub
|
|
|
Nach oben |
|
|
Elor
Anmeldungsdatum: 12.07.2013 Beiträge: 205 Wohnort: Konstanz
|
Verfasst am: 30.06.2016, 17:51 Titel: |
|
|
Naja, so langsam werde ich wach Den Buffer zum einlesen der Daten kann ich mir ja auch sparen und durch
Code: |
InPut #hFile, *(@Array(0)+ I)
|
ersetzen!
Die SUB sieht jetzt so aus
Code: |
Sub LoadArray (ByRef FileName As String, ByRef SecName As String, Array() As Single)
Dim As Integer Dimension, Counter= 1, hFile
ReDim As Integer Size()
Dim As String SecStr, sBuf
If FileExists (FileName) Then
SecStr= "["& uCase (SecName)& "]"
hFile= FreeFile ()
Open FileName For InPut As hFile
/' Array Sektion suchen '/
While Not Eof (hFile)
Line InPut #hFile, sBuf
If(uCase (sBuf) = SecStr) Then Exit While
Wend
If(uCase (sBuf) = SecStr) Then /' Sektion gefunden? '/
InPut #hFile, Dimension
ReDim Size(Dimension- 1)
For I As Integer= 0 To Dimension- 1
InPut #hFile, Size(I)
Counter= Counter* Size(I)
Next I
Select Case Dimension
Case 1: ''
ReDim Array(Size(0)- 1)
Case 2:
ReDim Array(Size(0)- 1, Size(1)- 1)
/' ... usw ... '/
End Select
/' wenn alles geklappt hat... '/
For I As Integer= 0 To Counter- 1
InPut #hFile, *(@Array(0)+ I)
Next I
End If
Close (hFile)
End If
End Sub
|
und die Anweisung
Code: |
#include Once „crt/string.bi“
|
kann man sich auch sparen.
Möchte mal wissen was da Gestern Morgen in meinem Kaffee war
Ok, dass Selektieren mit CASE ist zwar immer noch da, aber es sind ja nicht mehr als vier Dimensionen. Insofern ist das glaube ich eine Akzeptable Lösung. |
|
Nach oben |
|
|
|
|
Du kannst keine Beiträge in dieses Forum schreiben. Du kannst auf Beiträge in diesem Forum nicht antworten. Du kannst deine Beiträge in diesem Forum nicht bearbeiten. Du kannst deine Beiträge in diesem Forum nicht löschen. Du kannst an Umfragen in diesem Forum nicht mitmachen.
|
|